Some senseless babbling from Stewart Buckingham to All
on 11-13-99  05:22 about Communicator Fatal Error...

 SB> Hi,

 SB> I'm using Netscape Communicator 4.04 with Warp4 FP9 and Java 1.1.7.
 SB> Communicator was working fine but it is now failing to load with a
 SB> Fatal Error  box "Unable to parse OS2PREF.JS. Exiting". Any ideas how
 SB> to remedy this error? 

The only time I've seen this problem is when Netscape doesn't know where
it's located.  It determines that from an INI entry in the OS2.INI file,
which won't be there if you go back to an archive from before Netscape was
installed, or re-install OS/2.

If that's your problem, the following should solve it for you:

/* Create Netscape entry in OS2.INI */
call RxFuncAdd 'SysLoadFuncs','RexxUtil','SysLoadFuncs'
call SysLoadFuncs

cdir=directory()

parse arg dirname

if dirname='' then do
    say ''
    say 'Usage: nsini.cmd '
    say ''
    say 'dirname - location of Netscape'
    signal prgexit
end

check=directory(dirname)
if check='' then do
    say ''
    say 'Directory '||dirname||' not found.'
    signal prgexit
end

if stream('ns.pkg','c','query exists')\='' then nsver='2.02'
else if stream('ns40.pkg','c','query exists')\='' then nsver='4.0'
else if stream('ns46.pkg','c','query exists')\='' then nsver='4.6'
else do
    say ''
    say 'Directory = '||dirname
    say ''
    say 'The above directory does not appear to be where any version of'
    call charout ,'Netscape is located.  Continue (Y/N)? '
    ans=SysGetKey('noecho')
    ans=translate(ans)
    if ans='Y' then nop
    else do
        say ''
        say 'Aborting.'
        signal prgexit
    end
    say ''
    say ''
    say 'Unable to automatically determine the Netscape version.'
    say ''
    say 'Which version of netscape is installed?'
    say ''
    say '    1) 2.02'
    say '    2) 4.04'
    say '    3) 4.61'
    say ''
    call charout ,'Press 1-3 for appropriate version: '
    ok=0
    do until ok
        ans=SysGetKey('noecho')
        if ans\=1 & ans\=2 & ans\=3 then nop
        else do
            ok=1
            select
                when ans=1 then nsver='2.02'
                when ans=2 then nsver='4.0'
                when ans=3 then nsver='4.6'
                otherwise nop
            end
        end
    end
end

appname='Netscape'
keyname=nsver
keyvalue=dirname

check=SysIni('USER',appname,keyname,keyvalue)
if check\='' then do
    say ''
    say 'An error was encountered adding the Netscape INI entry.'
end
else do
    say ''
    say 'Netscape INI entry successfully added.'
end

prgexit:
call directory cdir
exit

Mike Ruskai
thannymeister@yahoo.com


... But how do we know your the REAL Angel of Death?

___ Blue Wave/QWK v2.20
--- Platinum Xpress/Win/Wildcat5! v3.0pr2
114/477
143/1