Hi David!
 On Tue Jul 11 David Roper wrote the following to George De Bruin:
 DR> Using TSE 2.0 is a dream come true, ....however what I miss the
   > most (besides my mind) from the old Qedit was the ability to
   > see the hex character value wherever the cursor was, on the top
   > row.  What page in the TSE 2.0 books is this feature found on?..
   > or better still, how do you do it?  It "couldn't" be gone :-( ????
   > Peace
 I don't think this was/is mentioned in the docs.  Like you though, I
 missed that feature a lot and was offered the following:
 -------------------------------------------------------------
 /**********************************************************************
   Macros for ToggleShowCurrChar:
   The mShowChar() macro duplicates QEdit's Show Current Character
   feature (which displays the character under the cursor on the command
   line).
   The mToggleShowChar() macro duplicates QEdit's ToggleShowCurChar
   command, which controls the mShowChar() macro.
 **********************************************************************/
 integer DisplayChars = FALSE
 proc mShowChar()
     integer n = CurrChar(),
             y = iif(Query(StatusLineAtTop), 1, Query(ScreenRows)),
             attr = Set(Attr, Query(StatusLineAttr))
     if Query(StatusLineUpdating)
         VGotoXY(74, y)
         PutStr(iif(n " +iif(n == _AT_EOL_, " ", "+ "),
                           Format(n:2:"0":16, "h,", n:-3)))
     endif
     Set(Attr, attr)
 end
 proc mToggleShowChar()
     DisplayChars = NOT DisplayChars
     if DisplayChars == TRUE
         Hook(_AFTER_UPDATE_STATUSLINE_, mShowChar)
     else
         UnHook(mShowChar)
         UpdateDisplay(_STATUSLINE_REFRESH_)
     endif
 end
 -------------------------------------------------------------
 I then added the above to my TSE.UI and also added the following to be
 sure it's loaded automatically:
 -------------------------------------------------------------
 /**********************************************************************
   This macro is called just after the first file is loaded, but before
   the user is given control, and before any hook functions are called.
 **********************************************************************/
 proc Main()
     mToggleShowChar()
 end
 /*********************************************************************/
 -------------------------------------------------------------
 This works great for me here - enjoy!
 Larry
---
---------------