Path: internal1.nntp.ash.giganews.com!border2.nntp.ash.giganews.com!border1.nntp.ash.giganews.com!firehose2!nntp4!intern1.nntp.aus1.giganews.com!border1.nntp.aus1.giganews.com!nntp.giganews.com!newsfeed.tpinternet.pl!news.atman.pl!news.intercom.pl!f124.n480!f127.n480!f112.n480!f200.n2432!f605.n774!f500.n123!f2000.n106!f1.n140!f5.n342!f512.n342!not-for-mail
Newsgroups: fido.4dos
Distribution: fido
From: Gerald Miller 
Date: Wed, 24 Dec 03 07:13:34 +0100
Subject: Multiple NodeDiff files
Message-ID: 
Organization: As funny as a house full of termites.
 2443/1181
Lines: 99
Xref: intern1.nntp.aus1.giganews.com fido.4dos:501

* Originally in 4DOS
* Crossposted in BATPOWER

Hello All,

I hope that everyone has all their shopping done by now and is ready to
enjoy the Holiday season.

There have been occasions when I have received multiple nodediff files
within a NodeDiff archive.

There have also been times when my uplink system has been down for over a
week and when he gets back online, I can receive multiple NodeDiff
archives.

My mailer batch file was able to deal with the second problem _until_ I
modified it to deal with the first problem....

I can't remember who posted the following 4DOS snippet or when it was
published, but I'll put it up again, in the hope that someone is able to
come up with something that will deal with both problems in a DOS and 4DOS
environment:

=== Begin Cut: DIFFRUN.BTM ===
*setlocal
:: Julian day setting
:: Setting VVOFD to the Friday, 21 days ago
set d_mod=-21 %+ gosub setting %+ set vvofd=%xjd

:: Setting VOFD to the Friday, 14 days ago
set d_mod=-14 %+ gosub setting %+ set vofd=%xjd

:: Setting OFD to the Friday, 7 days ago
set d_mod=-07 %+ gosub setting %+ set ofd=%xjd
:: Setting OFD to the FidoNet NodeList/NodeDiff standard of A##
set aofd=A%@substr[%ofd,1,2]

:: Setting FJD to the latest (past/upcoming) Friday
set d_mod=-00 %+ gosub setting %+ set fjd=%xjd
:: Setting FJD to the FidoNet NodeList/NodeDiff standard of A##
set afjd=A%@substr[%fjd,1,2]

:: Setting NFD to the Friday, 7 days from now
set d_mod=+07 %+ gosub setting %+ set nfd=%xjd
:: Setting NFD to the FidoNet NodeList/NodeDiff standard of A##
set anfd=A%@substr[%nfd,1,2]

:: Setting TJD to TODAY'S Julian day
set tjd=%@substr[000%_doy,2,-3]
:: Setting TJD to the FidoNet NodeList/NodeDiff standard of A##
set atjd=A%@substr[%tjd,1,2]

::   goto [rest of the program]
goto rest

:setting
:: D_DAY values:
::               Tuesday   = 0
::               Wednesday = 1
::               Thursday  = 2
::               Friday    = 3
::               Saturday  = 4
::               Sunday    = 5
::               Monday    = 6

set d_day=3
set d_mod=%@eval[%@date[%_date] %d_mod+0]
set d_up=%@eval[%d_mod %% 7]
iff "%d_day" != "" .and. %d_day. != %d_up. then
  if %d_day gt %d_up set d_up=%@eval[%d_up+7]
  set d_mod=%@eval[%d_mod-(%d_up-%d_day)]
endiff
  set tdate=%@makedate[%d_mod]
  set xjd=%@substr[000%@eval[%@date[%tdate]-%@date%=
[1-1-%@substr[%tdate,1,-2]]+1],2,-3]
return

:rest
echo  Setting VVOFD to the Friday, 21 days ago                     = %vvofd
echo  Setting VOFD to the Friday, 14 days ago                      = %vofd
echo  Setting OFD to the Friday, 7 days ago                        = %ofd
echo  Setting OFD to the FidoNet NodeList/NodeDiff standard of A## = %aofd
echo  Setting TJD to TODAY'S Julian day                            = %tjd
echo  Setting TJD to the FidoNet NodeList/NodeDiff standard of A## = %atjd
echo.
echo  Setting FJD to the LATEST (past/upcoming) Friday             = %fjd
echo  Setting FJD to the FidoNet NodeList/NodeDiff standard of A## = %afjd
echo.
echo  Setting NFD to the Friday, 7 days FROM NOW!                  = %nfd
echo  Setting NFD to the FidoNet NodeList/NodeDiff standard of A## = %anfd
endlocal
=== End Cut:   DIFFRUN.BTM ===

The above will specify an extension with an "A" for the ARC standard.
Substitute Z## for A## if you are using the ZIP standard.

           Cheers ... Gerald

... Failure is not an option - it comes bundled with Windows!