-=> On 05 Sep 96  20:51:28 you wrote to me <=-

Hi Rob,

MS> I have written an ARexx script which will "patch" AmyBW to
MS> ignore the packet version number.  I'm using a patched 2.11 now,
MS> and I've also tested it on version 2.10.

RH> Yes please, I have V2.13 registered and have not used it since
RH> the packet version probs :(

/*
 *  P A T C H A M Y B W
 *
 *  Patch AmyBW so that it ignores the mail packet version number
 *  The original version is named AmyBW:AmyBW.old
 *
 *  Tested on AmyBW version 2.10 and 2.11
 *
 *  Written by M. Stapleton of Graphic Bits
 *  This file is hereby donated to the public domain
 *
 *  Jul  1 1996
 *
 */

fname = 'AmyBW:AmyBW'
iname = fname'.old'

shell 'COMMAND' 'copy' fname 'to' iname

exit ChangeStr(fname, '55006726'x, '42006726'x)

/* Replace first occurence of old string with new in file iname */
ChangeStr:
parse arg iname,old,new
    len = length(old)
    if len ~= length(new) then do
        say 'Error: strings are of unequal length.'
        return 10
    end

    if ~open('f', iname, 'A') then do
        say 'Error: Can''t open file "'iname'".'
        return 10
    end
    call seek('f', 0, 'B')

    bufsize = 65535     /* Maximum ARexx string length */
    buf = readch('f', bufsize)
    bufsize = bufsize - len

    /* Search */
    do until eof('f')
        p = index(buf, old)
        if p>0 then break

        /* Leave the last len bytes in buf, in case */
        /* the pattern crosses the buffer boundary  */
        buf = right(buf, len) || readch('f', bufsize)
    end

    if p=0 then do
        say 'Pattern not found!'
        return 5
    end

    /* Replace */
    call seek('f', p-1-length(buf), 'C')
    call writech('f', new)
return 0

/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */

Let me know how it goes with 2.13.

Michael Stapleton of Graphic Bits.

 * AmyBW v2.10 *
... This tagline is encrypted
--- AdeptXBBS v1.07f (Registered)