AR>   BW> Is there any way to get WordPerfect 5.1+ for DOS to display a
AR>   BW> file directory list which can then be used with {Text In/Out}, 1,
AR>   BW> 3 (DOS text import with CR/LF to [Srt] in the "hot" zone)?
Auke, have you seen the VIEW macro to chose a graphics with? I
wonder if it can be used as a model for this sort of thing. It would
really be worthwhile.
{;}VIEW.WPM to view graphics files with WP 5.1+.~
{;}from WP Mag November 1995.~
{DISPLAY OFF}
{ON CANCEL}{GO}Quit~~{ON ERROR}{GO}Quit~~
{ASSIGN}Floppy~~{ASSIGN}List~{List}{List}~
{ASSIGN}ListF~{List}{DISPLAY ON}{List}~
{TEXT}Dir~Directory for graphics: ~
{ASSIGN}Drv~{MID}Dir~0~1~~
{FOR EACH}X~a~A~b~B~d~D~~
    {IF}"{VARIABLE}Drv~"="{VARIABLE}X~"~
        {ASSIGN}List~{List}{VARIABLE}X~:{Enter}~{ASSIGN}Floppy~1~
        {ASSIGN}ListF~{List}{VARIABLE}X~:{DISPLAY ON}{Enter}~
    {END IF}
{END FOR}
{Graphics}411{MENU OFF}{List}{VARIABLE}Dir~
{DISPLAY ON}{Enter}{CALL}List~
{LABEL}List~
{PROMPT}Highlight graphic and press (Enter)~
{PAUSE}{DISPLAY OFF}{Enter}
{IF}{SYSTEM}Menu~=305~
    {DISPLAY ON}{Enter}{Home}{Home}{Up}{GO}List~
{END IF}
{Cancel}{ASSIGN}Skipto~List~
{LABEL}Check~
{ASSIGN}Name~{SYSTEM}Entry~~{ASSIGN}Extpos~{LEN}Name~-3~
{ASSIGN}Ext~{MID}Name~{VARIABLE}Extpos~~3~~
{CASE}{VARIABLE}Ext~~WPG~Rtrv~CGM~Rtrv~PCX~Rtrv~EPS~Rtrv~TIF~Rtrv~~
{GO}{VARIABLE}Skipto~~
{LABEL}Rtrv~
1{IF}{STATE}&1024~Y{END IF}9{MENU OFF}
{LABEL}Menu~
{CHAR}X~{^]}1 N{^\}ext  {^]}2 P{^\}revious  {^]}3 S{^\}elect
        {^]}4 D{^\}elete  {^]}5 R{^\}eturn to List Files
        {^]}6 Q{^\}uit{Up}{Left}{Left}{Left}{Left}{^]}{VARIABLE}Name~{^\} ~
{DISPLAY OFF}
{CASE}{VARIABLE}X~~1~Next~n~Next~N~Next~{Down}~Next~{Page Down}~Next~
    2~Prev~p~Prev~P~Prev~{Up}~Prev~{Page Up}~Prev~3~Sel~s~Sel~S~Sel~
    4~Del~d~Del~D~Del~{Del}~Del~5~Ret~r~Ret~R~Ret~{List}~List~
    6~Quit~{Esc}~Quit~
    {OTHERWISE}~{GO}Quit~~
{LABEL}Next~
{Cancel}1{VARIABLE}List~{CALL}Floppy~{Right}
{ASSIGN}Next~{SYSTEM}Entry~~{ASSIGN}Skipto~Next~
{IF}"{VARIABLE}Name~"="{VARIABLE}Next~"~
    {Screen}{DISPLAY ON}{Screen}{GO}List~
{END IF}
{GO}Check~
{LABEL}Prev~
{Cancel}1{VARIABLE}List~{CALL}Floppy~{Left}
{ASSIGN}Skipto~Prev~{Enter}
{IF}{SYSTEM}Menu~=305~
    {Cancel}{Screen}{DISPLAY ON}{Screen}{GO}List~
{END IF}
{Cancel}{GO}Check~
{LABEL}Sel~
{MENU ON}{Exit}{Screen}{DISPLAY ON}{Screen}{QUIT}
{LABEL}Del~
{CHAR}X~Delete {VARIABLE}Name~?  N{^Q}o ({^]}Y{^\}es){Left}{Left}
{Left}{Left}{Left}{Left}{Left}{Left}{Left}{^]}) ~
{IF}"{VARIABLE}X~"="y"|"{VARIABLE}X~"="Y"~
    {Cancel}1{VARIABLE}List~{CALL}Floppy~{Del}Y{ASSIGN}X~~
    {Screen}{DISPLAY ON}{Screen}{GO}List~
{ELSE}{GO}Menu~
{END IF}
{LABEL}Ret~
{Cancel}1{MENU OFF}{VARIABLE}ListF~{CALL}Floppy~{GO}List~
{LABEL}Floppy~
{IF}{VARIABLE}Floppy~=1~N{VARIABLE}Name~{Enter}{END IF}{RETURN}
{LABEL}Quit~
{DISPLAY OFF}
{IF}{STATE}&4~{QUIT}{ELSE}{Cancel}{GO}Quit~{END IF}
 * OLX 2.2 * don_nickell@nm-us.campus.mci.net
--- Maximus 2.02
---------------