Below is an automated script for the CE-232 Interface donated by  Mr. Rich 
McNamee.  Simply cut out the below text exactly between  the "cut here" lines 
and save it in your CE-232 Script directory  as the filename LINK123.SCR and 
then run it at your pleasure.
This script effectively links three SEARCH Banks into one on your 
CE-232-equipped PRO-2004/5/6 scanner.  A slight modification could  link for 
or more including all ten Search Banks into one.
Have fun!
====================[ cut here ]==========================
/ LINK123.SCR    Rich McNamee  (K2QG)   30 August 1996
/
/
/ This script will link three search ranges 1, 2, and 3.
/
/ The upper frequency limit for each search range must be an
/ exact multiple of the step size or the end of the search
/ range will never be seen by the script.  If that is allowed
/ to occur the script will "stick" in one search range.
/
/ In an attempt to make this easier in the  869-894 mhz
/ range, the script forces the step size to 30 khz and looks for a
/ frequency greater than (upper limit frequency - 0.030 khz).
/
/ In all other frequency ranges, it is up to you to ensure
/ that a valid upper limit is entered.
/
/
/  NOTE:  Occasionally, the script will "miss" the upper limit
/  frequency.  This will cause the current search range to be
/  be repeated more than once.
/
keyclr
MSG1-                     *****  LINK123.SCR  *****
MSG2-
MSG3-
MSG4-             This script links search ranges 1, 2, and 3,
MSG5-             together.
MSG6-
MSG7-
MSG8-
MSG9-      Press "C" to continue....
IDLE UNTIL KEY = C     / wait for "c" key to be pressed
MSG1-                     *****  LINK123.SCR  *****
MSG2-
MSG3-
MSG4-            Reading LIMIT frequencies for search ranges 1, 2, and 3
MSG5-
MSG6-
MSG7-
MSG8-
MSG9-
P             / put the scanner into the program mode
1             / select search bank 1
I             / get lower frequency limit
VALUE@0 = FREQ
I             / get upper frequency limit
VALUE@1 = FREQ
P             / puts the scanner into the program mode
2             / select search bank 2
I             / get lower frequency limit
VALUE@2 = FREQ
I             / get upper frequency limit
VALUE@3 = FREQ
P             / puts the scanner into the program mode
3             / select search bank 3
I             / get lower frequency limit
VALUE@4 = FREQ
I             / get upper frequency limit
VALUE@5 = FREQ
SEARCH UP     / starts the scanner searching up in search range 1
1
MSG1-
MSG2-
MSG3-      LINK123 Script
MSG4-
MSG5-      Searching ranges 1, 2, & 3
MSG6-
MSG7-      Press "H" to halt the script at the end of range 1....
MSG8-      Or:
MSG9-      Ctrl "A" to end immediately.
DO  //start of loop
  IF  VALUE@0 >= 869.0400 THEN
    IF VALUE@1 <= 894.0000 THEN
      STEP = 30                    / force 30 khz step in this range
      VALUE@8 = VALUE@1 - .030
      IDLE UNTIL FREQ > VALUE@8
    ELSE
      IDLE UNTIL FREQ = VALUE@1
    ENDIF
  ELSE
    IDLE UNTIL FREQ = VALUE@1
  ENDIF
  2
  IF  VALUE@2 >= 869.0400 THEN
    IF VALUE@3 <= 894.0000 THEN
      STEP = 30                    / force 30 khz step in this range
      VALUE@9 = VALUE@3 - .030
      IDLE UNTIL FREQ > VALUE@9
    ELSE
      IDLE UNTIL FREQ = VALUE@3
    ENDIF
  ELSE
    IDLE UNTIL FREQ = VALUE@3
  ENDIF
  3
  IF  VALUE@4 >= 869.0400 THEN
    IF VALUE@5 <= 894.0000 THEN
      STEP = 30                    / force 30 khz step in this range
      VALUE@7 = VALUE@5 - .030
      IDLE UNTIL FREQ > VALUE@7
    ELSE
      IDLE UNTIL FREQ = VALUE@5
    ENDIF
  ELSE
    IDLE UNTIL FREQ = VALUE@5
  ENDIF
  1
LOOP UNTIL KEY = H  //loop until the "h" key is pressed
MAN
MSG1-
MSG2-
MSG3-
MSG4-
MSG5-
MSG6-
MSG7-
MSG8-
MSG9-
//end of file link123.scr
============[ cut here ]======================================
Bill Cheek | Internet: bcheek@cts.com | Compu$erve: 74107,1176
Windows 95 Juggernaut Team | Microsoft MVP
--- Hertzian Mail+
---------------