From: "Sammy Mitchell" 
@Date: Fri, 28 Feb 2003 16:39:29 -0500
@Sender: semware-owner{at}sawasdi.apana.org.au



Scott Wagner said:
>The only "weird" thing about this is that ldflist (in v4 at
>least) appears to load the last file of the list first.

Tom Martin added:
>This works pretty much the way I want.  Now, if we could
>just modify the ldflist.mac to issue a "next file in ring"
>command after it finished opening all of the files....

Here is a new version I've been playing with, that fixes
that problem.  It is simpler than the current shipping
version, in that it expects each line to be a valid
filename, except that it will also recognized "grep files".

// load files listed by grep, in format: File:filename
// otherwise, load files, one per line

integer proc findGreppedFile()
    return (lFind("File: \c", "^x"))
end

proc mAddFileToRing(var integer cur_id, var integer count)
    integer start_id

    MarkToEOL()
    start_id = GotoBufferId(cur_id)
    cur_id = AddFileToRing(GetMarkedText())
    count = count + 1
    GotoBufferId(start_id)
end

proc main()
    integer start_id, cur_id, count, changed

    start_id = GetBufferId()
    cur_id = start_id
    count = 0
    PushBlock()
    PushPosition()

    BegFile()
    if findGreppedFile()
        repeat
            mAddFileToRing(cur_id, count)
            EndLine() // so find will start on next line
        until not findGreppedFile()
    else
        repeat
            mAddFileToRing(cur_id, count)
        until not Down()
    endif

    PopPosition()
    PopBlock()
    changed = FileChanged()
    NextFile()
    if not changed
        AbandonFile(start_id)
    endif
    Message(count, " File(s) loaded.")
end


--
TSEPro Mailing List
List Maintenance: www.semware.com/html/list.htm



---
[sawasdi.apana.org.au] (3:800/846.13)